10 REM ***********************************
20 REM *** Password generation program ***
30 REM *** For use with Burglar Alarm  ***
40 REM ***   (C) 1987, 2026 Rich Teer  ***
50 REM ***********************************
60 PROC_init
70 MODE 0
80 PROC_centre("PASSWORD CREATOR", 5)
90 INPUT TAB(0, 10); "Please enter required Password: " password$
100 PRINT
110 PRINT "The encoded Password is: ";
120 FOR loop = 1 TO LEN(password$)
130   PRINT "&";
140   value = FN_encode(MID$(password$, loop, 1))
150   PRINT; ~value; ", ";
160   NEXT loop
170 VDU 127
180 PROC_centre("Press <RETURN> when ready ", 15)
190 REPEAT UNTIL GET = 13
200 END
210
220 DEF PROC_init
230 *TV 0 1
240 DIM keys(9)
250 FOR loop = 0 TO 9
260   READ data
270   keys(loop) = data
280   NEXT loop
290 ENDPROC
300
310 DEF PROC_centre(x$, y)
320 x = 40 - (LEN(x$) DIV 2)
330 PRINT TAB (x, y); x$
340 ENDPROC
350
360 DEF FN_encode(start$)
370 index = (ASC(start$)) - 48
380 = keys(index)
390
400 DATA &AF, &DD, &BD, &7D, &DB, &BB, &7B, &D7, &B7, &77, &CF, &6F
